it-swarm-ja.com

WindowsPEでのVB.NETの実行

VisualBasicでアプリを作りました。そして、Windows PEで実行したいと思います。BartPEなどのディストリビューションではなく、Microsoftから入手できるストックPEです。 WindowsPEはデフォルトで.NETをサポートしていませんが、すべてのライブラリをインストールする方法が必要だと思います。 32ビットバージョンのWindowsPE 4.0(Windows 8.0ベース)を使用していますが、最新のWindows PE10.0.14393.0も使用できます。するべきか?優先順位は、VB.NETアプリを実行することです。みんな、ありがとう!

2
PetrMolek

これは、最新バージョンのWindows PEで機能します(したがって、Windows 10のエディションと同様に、Windows 8のものでも問題ありません)。私は個人的に Windows 8.1 ADK を使用して成功しました。インストーラーの機能選択段階で、展開ツールともちろんWinPEがあることを確認してください。

次に、このバッチスクリプトの適切に変更されたバージョンを、「展開およびイメージングツール環境」から管理者として実行できます。

@echo off
set _=%CD%
set PF=C:\Program Files
if exist "C:\Program Files (x86)\" set PF=C:\Program Files (x86)
echo Preparing PE workspace...
call copype.cmd x86 scratch\ > nul
cd %_%
echo Mounting image...
dism /Mount-Wim /WimFile:scratch\media\sources\boot.wim /index:1 /MountDir:scratch\mount > nul
echo Injecting WMI packages...
dism /image:scratch\mount /Add-Package /PackagePath:"%PF%\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\x86\WinPE_OCs\WinPE-WMI.cab" > nul
dism /image:scratch\mount /Add-Package /PackagePath:"%PF%\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\x86\WinPE_OCs\en-us\WinPE-WMI_en-us.cab" > nul
echo Injecting .NET packages...
dism /image:scratch\mount /Add-Package /PackagePath:"%PF%\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\x86\WinPE_OCs\WinPE-NetFX.cab" > nul
dism /image:scratch\mount /Add-Package /PackagePath:"%PF%\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\x86\WinPE_OCs\en-us\WinPE-NetFx_en-us.cab" > nul
echo Adding files...
REM: Add commands to copy in the appropriate files here
REM: Or insert a "pause" so you can manually do it in Explorer
echo Unmounting image...
dism /Unmount-Wim /MountDir:scratch\mount /Commit > nul
echo Finishing up...
move scratch\media\sources\boot.wim boot.wim > nul
rmdir /s /q scratch > nul

%PF%のものがそこにあるので、Windows Kitsフォルダーがどこにあるかを自動的に検出できます。これは、技術者のコンピューターのビット数によって異なります。別のバージョンのADKを使用する場合は、8.1のすべてのインスタンスをキットのフォルダー名に変更してください。重要な部分は、WMIおよび.NETパッケージを追加する場所です。 (.NETのものはWMIに依存します。)生成される最終的なboot.wimファイルは、WinPE環境と同じビット数の.NETアプリケーションを実行できます。

3
Ben N