it-swarm-ja.com

emacsの関数間をすばやくナビゲート/ジャンプする方法は?

Emacsの関数間をすばやくナビゲート/ジャンプする方法は? emacsの関数にすばやくジャンプする方法を探しています。私はそれを行うためにemacs検索を使用していますが、それは遅すぎて失敗します。たとえば、関数プロトタイプや関数呼び出しに一致しない文字列を入力する必要があります。関数のタイプとそれにパラメータータイプの懇願を含める必要があります。プログラムで使用されるコーディング構文スタイルによっては、実行するのが難しい/避けられません。正確に私が探しているのは、関数名だけを入力して、物乞いにジャンプするものです。私の現在の言語はLinux上のCです。しかし、他のプログラミング言語やプラットフォームにそのような機能がある場合は、私にも見せてください。非常に高く評価されます。

お願い:「IDEを使う」ことを提案しないでください。私はemacsで大丈夫です。

8
Jack

M-x imenuを使用すると、同じファイル内の関数にジャンプできます。簡単にアクセスできるようにSuper-iにバインドしました。

11
legoscia

私はEmacsに統合されたcscopeを使用してきましたが、関数や変数などを検索したり、それらの間をジャンプしたりするのに非常に効果的です。

編集:.emacs(または.xemacs/init.el)にあります:

(require 'xcscope)
(setq cscope-do-not-update-database t)

次に、必要に応じてソースファイルに対してcscopeを手動で実行します(Linuxカーネルの場合はmake cscope、これは他の多くの大規模プロジェクトでも機能します)。

3
Mats Petersson

他の人がすでに提案しているように、私もImenuを排他的に使用してバッファ内を移動します。 Imenuのidoインターフェイスを使用して、これを行うと非常に便利です。これがido-imenuの設定です。 (これは、emacswikiページにある関数から少し変更されたバージョンです)

(defun ido-imenu ()
  "Update the imenu index and then use ido to select a symbol to navigate to.
Symbols matching the text at point are put first in the completion list."
  (interactive)
  (imenu--make-index-alist)
  (let ((name-and-pos '())
        (symbol-names '()))
    (flet ((addsymbols
            (symbol-list)
            (when (listp symbol-list)
              (dolist (symbol symbol-list)
                (let ((name nil) (position nil))
                  (cond
                   ((and (listp symbol) (imenu--subalist-p symbol))
                    (addsymbols symbol))

                   ((listp symbol)
                    (setq name (car symbol))
                    (setq position (cdr symbol)))

                   ((stringp symbol)
                    (setq name symbol)
                    (setq position
                          (get-text-property 1 'org-imenu-marker symbol))))

                  (unless (or (null position) (null name))
                    (add-to-list 'symbol-names name)
                    (add-to-list 'name-and-pos (cons name position))))))))
      (addsymbols imenu--index-alist))
    ;; If there are matching symbols at point, put them at the beginning
    ;; of `symbol-names'.
    (let ((symbol-at-point (thing-at-point 'symbol)))
      (when symbol-at-point
        (let* ((regexp (concat (regexp-quote symbol-at-point) "$"))
               (matching-symbols
                (delq nil (mapcar
                           (lambda (symbol)
                             (if (string-match regexp symbol) symbol))
                           symbol-names))))
          (when matching-symbols
            (sort matching-symbols (lambda (a b) (> (length a) (length b))))
            (mapc
             (lambda (symbol)
               (setq symbol-names (cons symbol (delete symbol symbol-names))))
             matching-symbols)))))
    (let* ((selected-symbol (ido-completing-read "Symbol? " symbol-names))
           (position (cdr (assoc selected-symbol name-and-pos))))
      (Push-mark)
      (if (overlayp position)
          (goto-char (overlay-start position))
        (goto-char position)))))

(global-set-key (kbd "C-x C-i") 'ido-imenu)

そして、私は使用することができます C-xC-iimenuをサポートする多くの言語モードで

3
kindahero