it-swarm-ja.com

VIM ci "と同等のEmacs?

EmacsにはVIMsci "コマンドと同等のものがありますか?基本的に、引用符のセット内のテキストを置き換えたいと思います。

Vimでは、ci)またはci]またはci}を使用して「内部*を変更」することができます。

13
erikcw

頭のてっぺんから、最も近いコマンドはM-z "で、ポイントから次の "文字の出現まですべてを削除します。

C-M-k、別名「キルバランス式」もあります。これは、「バランス式」の現在のモード定義と現在ポイントにある文字(つまり、カーソルが開口部 '"'または '('など)にある場合にのみ機能します。

19
Justin Smith

ジャスティンの提案と同様に、C-M-SPACEは「mark-sexp」を提供します。これは、バランスをとるパレン、見積もりなどを選択し、C-wまたはその他の方法でそれをなくすことができます。削除する前に、削除しようとしているものを確認したい場合は...

7
Brian Postow

はい! EmacsのVIMsci "コマンドに相当するものは... ci" :-)
http://www.emacswiki.org/emacs-de/Vimpulse

この質問に出くわしました。これが私のために働いたカスタムソリューションです:

(defun seek-backward-to-char (chr)
  "Seek backwards to a character"
  (interactive "cSeek back to char: ")
  (while (not (= (char-after) chr))
    (forward-char -1)))


(defun delete-between-pair (char)
  "Delete in between the given pair"
  (interactive "cDelete between char: ")
  (seek-backward-to-char char)
  (forward-char 1)
  (zap-to-char 1 char)
  (insert char)
  (forward-char -1))

次に、delete-between-pairを任意のキーにバインドします。私にとっては、C-ziにバインドしています。

3
ozataman

Markit と呼ばれるVim機能のいくつかを提供するマイナーモードを作成しました。

2
Daimrod

VIMのci機能についてはわかりませんが、Emacs regexp replaceを見たことがありますか?正確なセマンティクスや、比較してどれほど簡単に使用できるかについて話すことはできませんが、それは私があなたが望むと思うものに使用するものです。

2
Michael H.

これは私がVimに欠けていたものであり、zap-to-charそれを正しくカットしなかったようです。

これが「ci」と「ca」を再現するための私の謙虚な試みです。

(defun change-outer (str)
  (interactive "sChange outer: ")
  (condition-case nil
      (search-backward str (line-beginning-position))
    (error (search-forward str (line-end-position))
       (forward-char -1)))
  (kill-sexp)
)

(defun change-inner (str)
  (interactive "sChange inner: ")
  (condition-case nil
      (search-backward str (line-beginning-position))
    (error (search-forward str (line-end-position))
       (forward-char -1)))
  (Push-mark)
  (forward-sexp)
  (forward-char -1)
  (exchange-point-and-mark)
  (forward-char 1)
  (kill-region (point) (mark))
)

Search-forward/search-backwardの3番目の(オプションの)パラメーターは、検索が失敗した場合の対処方法を示すためのものであるため、通常、condition-caseは必要ありません。しかし、何らかの理由で、最初の検索の3番目のパラメーターとして2番目の検索を配置すると、奇妙な動作が発生します。

0
vladimird

Magnars(EmacsRocksサイトの作者)は、あなたが求めていることを正確に実行するためにこのプラグインを作成しました。

https://github.com/magnars/change-inner.el

もちろん、Evilモードを使用することもできます。

0
Doug

ここで解決策を試しましたが、それぞれが何らかの形で欲しがっていたので、これを思いつきました。開始区切り文字または終了区切り文字のいずれかを受け入れ、組み込みのEmacs関数を使用して、区切り文字の変換テーブルが不要になります。

(defun change-inner (prefix character)
  "Kill region inside delimiters, using either beginning or
ending delimiter.  With prefix arg, kill including delimiters."

  (interactive "p\nc")
  (let ((initial-point (point))
        (start)
        (end)
        (move-point-by (if (> prefix 1) 0 1)))

    (condition-case nil
        (progn
          ;; Search forward for given char
          (search-forward (char-to-string character))
          (setq end (- (point) move-point-by))

          (condition-case nil
              (backward-sexp)
            (error (backward-list)))

          (setq start (+ (point) move-point-by))
          (kill-region start end)
          (or prefix (forward-char)))

      (error (progn
               ;; Reset and search backward for given char
               (goto-char initial-point)
               (search-backward (char-to-string character))
               (setq start (+ (point) move-point-by))

               (condition-case nil
                   (forward-list)
                 (error (forward-sexp))))

             (setq end (- (point) move-point-by))
             (kill-region start end)
             (or prefix (backward-char))))))
(global-set-key (kbd "M-i") 'change-inner)

(defun change-outer ()
  (interactive)
  (let ((current-prefix-arg '(4)))
    (call-interactively 'change-inner)))
(global-set-key (kbd "M-o") 'change-outer) 
0
blujay

これが私のバージョンで、一致する文字のペア内(またはそれを含む)のすべてを削除します。文字ペアは、一致する開始/終了文字がわかるようにリストで定義されます。変更の場合は「C-ci」に、すべての変更の場合は「C-ca」にマッピングしました。

また、削除した文字をクリップボードにコピーして、後で貼り付けることもできます。

; Re-create ci" ca"...
(defun seek-backward-to-char (chr)
  "Seek backwards to a character"
  (interactive "cSeek back to char: ")
  (while (not (= (char-after) chr))
    (forward-char -1)))

(setq char-pairs
      '(( ?\" . ?\" )
        ( ?\' . ?\' )
        ( ?\( . ?\) )
        ( ?\[ . ?\] )
        ( ?\{ . ?\} )
        ( ?<  . ?>  )))

(defun get-char-pair (chr)
  (let ((result ()))
    (dolist (x char-pairs)
      (setq start (car x))
      (setq end (cdr x))
      (when (or (= chr start) (= chr end))
        (setq result x)))
      result))

(defun get-start-char (chr)
  (car (get-char-pair chr)))
(defun get-end-char (chr)
  (cdr (get-char-pair chr)))

(defun seek-to-matching-char (start end count)
  (while (> count 0)
    (if (= (following-char) end)
        (setq count (- count 1))
      (if (= (following-char) start)
          (setq count (+ count 1))))
    (forward-char 1)))

(defun seek-backward-to-matching-char (start end count)
  (if (= (following-char) end)
      (forward-char -1))
  (while (> count 0)
    (if (= (following-char) start)
        (setq count (- count 1))
      (if (= (following-char) end)
          (setq count (+ count 1))))
    (if (> count 0)
        (forward-char -1))))

(defun delete-between-pair (char)
  "Delete in between the given pair"
  (interactive "cDelete between char: ")
  (seek-backward-to-matching-char (get-start-char char) (get-end-char char) 1)
  (forward-char 1)
  (setq mark (point))
  (seek-to-matching-char (get-start-char char) (get-end-char char) 1)
  (forward-char -1)
  (kill-region mark (point)))

(defun delete-all-pair (char)
  "Delete in between the given pair and the characters"
  (interactive "cDelete all char: ")
  (seek-backward-to-matching-char (get-start-char char) (get-end-char char) 1)
  (setq mark (point))
  (forward-char 1)
  (seek-to-matching-char (get-start-char char) (get-end-char char) 1)
  (kill-region mark (point)))

(global-set-key (kbd "C-c i") 'delete-between-pair)
(global-set-key (kbd "C-c a") 'delete-all-pair)
0
user2549917